.SUBCKT AO3401 4 1 2

M1  3 5 8 8 PMOS W=998956u  L=1u 

M2  8 5 8 3 NMOS W=998956u  L=0.5u

R1  7 3     RTEMP 25E-3

LD  4 7 0.5E-9

LS  8 2 1E-9

RG 1 6 6

LG 6 5 3E-9

CGS 5 2     1E-12

DBD 3 8     DBD

**************************************************************************

.MODEL  PMOS       PMOS  (LEVEL  = 3               TOX    = 2.5E-8

+ RS     = 2E-4           RD     = 0               NSUB   = 2E17  

+ UO     = 120             THETA  = 0.2		   VTO=-1.2

+ VMAX   = 5e6             XJ     = 4E-7            KAPPA  = 1.1

+ ETA    = 0              TPG    = 1  

+ IS     = 0              LD     = 0                           

+ CGSO   = 0              CGDO   = 0               CGBO   = 0 

+ NFS    = 0         DELTA  = 0)

*************************************************************************

.MODEL  NMOS       NMOS (LEVEL   = 3               TOX    = 2.5E-8

+NSUB    = 4E16    VTO=1.1    TPG    = -1)   

*************************************************************************

.MODEL DBD D (CJO=147E-12     VJ=0.6    M=0.5

+RS=0.0 FC=0.5 IS=1E-11 TT=1e-8 N=1.0 BV=36 IBV=1E-4)

*************************************************************************

.MODEL RTEMP RES (TC1=3.0E-3   TC2=0)

*************************************************************************

.ENDS