.SUBCKT AOD408 4 1 2
M1  10 5 7 8  NMOS W=1312500u  L=1u 
M2  8  5 8 10  PMOS W=1312500u  L=1.1u
R1  4 10      RTEMP 10.8E-3
CGS 5 7     100E-12
* RGS 1 2     1M
R2  8 7     0.1E-3
*CBS 8 7     210E-12
*R3  9 4     0.73E-3
* CDB 4 5     5E-12
* Parasitic Body BJT: E: 7, B: 8, C: 9
Q3  10 8 7   QBODY
RG  6 5 0.7
LG  1 6 3n
LS  2 7 3n
* BC breakdown by avalanche diode
*********************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 5               TOX    = 4.5E-8
+ RS     = 3E-4           RD     = 0               VTO=2.4  
+ UO =  800	  THETA  = 0.1            NSUB=2.0e17	
+ VMAX   = 8E6            XJ     = 5.1E-7          LAMBDA=1.5
+ ETA    = 0              TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 )
**********************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 4.5E-8
+NSUB    = 1.2E16  NSS=-4E11 TPG    = -1)   
**********************************************************************
.MODEL QBODY NPN (IS=1.2E-12   Xti=0     Eg=1.11  
+BR=1     CJC=260E-12    MJC=0.35  
+TR=3E-9 XTB=0 VJC=0.55)
**********************************************************************
.MODEL RTEMP RES (TC1=3.6E-3   TC2=1E-6)
**********************************************************************
.ENDS