.SUBCKT AOD460 4 1 2
M1  10 5 7 8  NMOS W=1114708u  L=1.0u 
M2  8  5 8 10  PMOS W=1720000u  L=0.4u
R1  4 10      RTEMP 8.5E-3
CGS 5 7     1E-12
* RGS 1 2     1M
R2  8 7     0.10E-3
*CBS 8 7     310E-12
*R3  9 4     3E-3
* CDB 4 5     5E-12
* Parasitic Body BJT: E: 7, B: 8, C: 9
Q3  10 8 7   QBODY
RG  6 5 0.93
LG  1 6 3n
LS  2 7 3n
* BC breakdown by avalanche diode
*DBD 8 9 DBD
*********************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 5               TOX    = 4.5E-8
+ RS     = 3E-4           RD     = 0               VTO=2.6  
+ UO =  930	  THETA  = 0.1            NSUB=2.0e17
+ VMAX   = 8E6            XJ     = 5.1E-7          KAPPA  = 6
+ ETA    = 0              TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ NFS    = 2E10           DELTA  = 0.1)
**********************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 4.5E-8
+NSUB    = 5.5E16           TPG    = -1)   
**********************************************************************
.MODEL QBODY NPN (IS=1.5E-12   Xti=1       Eg=1.11     
+ BR=1    NC=2
+ CJC=330E-12    MJC=0.4   VJC=0.55        
+ TR=3E-9 XTB=0 )
**********************************************************************
.MODEL DBD D (CJO=1.2E-12     VJ=0.55    M=0.497
+RS=0  FC=0.5 IS=5E-12 TT=15E-9 N=1.0 BV=30 IBV=250E-6)
**********************************************************************
.MODEL RTEMP RES (TC1=3.8E-3   TC2=3.6E-6)
**********************************************************************
.ENDS